blob: e1dc969ab28dc7cc29a2894d5d43ee4afc7724a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
|
; Keywords
[
"as"
"const"
"external"
"let"
"opaque"
"pub"
"todo"
"try"
] @keyword
; Function Keywords
[
"fn"
"type"
] @keyword.function
; Imports
[
"import"
] @include
; Conditionals
[
"case"
"if"
] @conditional
; Exceptions
[
"assert"
] @exception
; Punctuation
[
"("
")"
"<<"
">>"
"["
"]"
"{"
"}"
] @punctuation.bracket
[
","
"."
] @punctuation.delimiter
[
"#"
] @punctuation.special
; Operators
[
"%"
"&&"
"*"
"*."
"+"
"+."
"-"
"-."
"->"
".."
"/"
"/."
":"
"<"
"<."
"<="
"<=."
"="
"=="
">"
">."
">="
">=."
"|>"
"||"
] @operator
; Identifiers
(identifier) @variable
; Comments
[
(module_comment)
(statement_comment)
(comment)
] @comment
; Unused Identifiers
[
(discard)
(hole)
] @comment
; Modules & Imports
(module ("/" @namespace)?) @namespace
(import alias: ((identifier) @namespace)?)
(remote_type_identifier module: (identifier) @namespace)
(unqualified_import name: (identifier) @function)
; Strings
(string) @string
; Bit Strings
(bit_string_segment) @string.special
; Numbers
[
(integer)
(float)
(bit_string_segment_option_unit)
] @number
; Function Parameter Labels
(function_call arguments: (arguments (argument label: (label) @symbol ":" @symbol)))
(function_parameter label: (label)? @symbol name: (identifier) @parameter (":" @parameter)?)
; Records
(record arguments: (arguments (argument label: (label) @property ":" @property)?))
(record_pattern_argument label: (label) @property ":" @property)
(record_update_argument label: (label) @property ":" @property)
(field_access record: (identifier) @variable field: (label) @property)
; Type Constructors
(data_constructor_argument label: (label) @property ":" @property)
; Type Parameters
(type_parameter) @parameter
; Types
((type_identifier) @type (#not-any-of? @type "True" "False"))
; Booleans
((type_identifier) @boolean (#any-of? @boolean "True" "False"))
; Type Variables
(type_var) @type
; Tuples
(tuple_access index: (integer) @operator)
; Functions
(function name: (identifier) @function)
(public_function name: (identifier) @function)
(function_call function: (identifier) @function)
(function_call function: (field_access field: (label) @function))
; External Functions
(public_external_function name: (identifier) @function)
(external_function name: (identifier) @function)
(external_function_body (string) @namespace . (string) @function)
; Pipe Operator
(binary_expression operator: "|>" right: (identifier) @function)
; Parser Errors
(ERROR) @error
|
