chore: create ecma base for use in js and ts which fixes jsx issues

1 files changed, 61 insertions, 0 deletions

diff --git a/queries/ecma/locals.scm b/queries/ecma/locals.scm
new file mode 100644
index 00000000..2f501f3a
--- /dev/null
+++ b/queries/ecma/locals.scm
@@ -0,0 +1,61 @@
+; Scopes
+;-------
+
+(statement_block) @scope
+(function) @scope
+(arrow_function) @scope
+(function_declaration) @scope
+(method_definition) @scope
+(for_statement) @scope
+(for_in_statement) @scope
+(catch_clause) @scope
+
+; Definitions
+;------------
+
+(formal_parameters
+  (identifier) @definition.parameter)
+
+(formal_parameters
+  (object_pattern
+    (identifier) @definition.parameter))
+
+; function(arg = []) {
+(formal_parameters
+  (assignment_pattern
+    (shorthand_property_identifier) @definition.parameter))
+
+; x => x
+(arrow_function
+  parameter: (identifier) @definition.parameter)
+
+(formal_parameters
+  (object_pattern
+    (shorthand_property_identifier) @definition.parameter))
+
+(formal_parameters
+  (array_pattern
+    (identifier) @definition.parameter))
+
+(formal_parameters
+  (rest_parameter
+    (identifier) @definition.parameter))
+
+(variable_declarator
+  name: (identifier) @definition.var)
+
+(import_specifier
+  (identifier) @definition.import)
+
+(namespace_import
+  (identifier) @definition.import)
+
+(function_declaration
+  ((identifier) @definition.var)
+   (#set! definition.var.scope parent))
+
+; References
+;------------
+
+(identifier) @reference
+(shorthand_property_identifier) @reference