blob: 5462bae4f5a68e0704632a81a51374f48b6d3ac5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Based off:
# https://github.com/NixOS/nixpkgs/blob/master/nixos/modules/services/misc/nix-optimise.nix
# When making changes please try to keep it in sync.
{ config, lib, ... }:
let
inherit (lib)
mdDoc
mkIf
mkOption
mkRemovedOptionModule
optionalString
types
;
cfg = config.nix.optimise;
in
{
imports = [
(mkRemovedOptionModule [ "nix" "optimise" "dates" ] "Use `nix.optimise.interval` instead.")
];
###### interface
options = {
nix.optimise = {
automatic = mkOption {
type = types.bool;
default = false;
description = mdDoc "Automatically run the nix store optimiser at a specific time.";
};
# Not in NixOS module
user = mkOption {
type = types.nullOr types.str;
default = null;
description = mdDoc "User that runs the store optimisation.";
};
interval = mkOption {
type = types.attrs;
default = { Hour = 3; Minute = 15; };
description = mdDoc "The time interval at which the optimiser will run.";
};
};
};
###### implementation
config = mkIf cfg.automatic {
launchd.daemons.nix-optimise = {
environment.NIX_REMOTE = optionalString config.nix.useDaemon "daemon";
serviceConfig = {
ProgramArguments = [
"/bin/sh" "-c"
"/bin/wait4path ${config.nix.package} && exec ${config.nix.package}/bin/nix-store --optimise"
];
RunAtLoad = false;
StartCalendarInterval = [ cfg.interval ];
UserName = cfg.user;
};
};
};
}
|
