3 files changed, 181 insertions, 5 deletions
diff --git a/modules/services/monitoring/netdata.nix b/modules/services/monitoring/netdata.nix
new file mode 100644
index 0000000..da0809c
--- /dev/null
+++ b/modules/services/monitoring/netdata.nix
@@ -0,0 +1,55 @@
+{ config, lib, pkgs, ... }:
+with lib;
+let
+  cfg = config.services.netdata;
+
+in {
+  meta.maintainers = [ lib.maintainers.rsrohitsingh682 or "rsrohitsingh682" ];
+
+  options = {
+    services.netdata = {
+      enable = mkEnableOption "Netdata daemon";
+
+      package = lib.mkPackageOption pkgs "netdata" {};
+
+      config = mkOption {
+        type = types.lines;
+        default = "";
+        description = "Custom configuration for Netdata";
+      };
+
+      workDir = mkOption {
+        type = types.path;
+        default = "/var/lib/netdata";
+        description = "Working directory for Netdata";
+      };
+
+      logDir = mkOption {
+        type = types.path;
+        default = "/var/log/netdata";
+        description = "Log directory for Netdata";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    environment.systemPackages = [ cfg.package ];
+
+    launchd.daemons.netdata = {
+      serviceConfig = {
+        Label = "netdata";
+        KeepAlive = true;
+        WorkingDirectory = cfg.workDir;
+        StandardErrorPath = "${cfg.logDir}/netdata.log";
+        StandardOutPath = "${cfg.logDir}/netdata.log";
+      };
+      command = lib.getExe cfg.package;
+    };
+
+    environment.etc."netdata/netdata.conf".text = cfg.config;
+
+    system.activationScripts.preActivation.text = ''
+      mkdir -p ${cfg.workDir}
+    '';
+  };
+}
diff --git a/modules/services/monitoring/prometheus-node-exporter.nix b/modules/services/monitoring/prometheus-node-exporter.nix
new file mode 100644
index 0000000..7f58055
--- /dev/null
+++ b/modules/services/monitoring/prometheus-node-exporter.nix
@@ -0,0 +1,121 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  inherit (lib)
+    concatStringsSep
+    escapeShellArgs
+    getExe
+    mkEnableOption
+    mkIf
+    mkOption
+    mkPackageOption
+    mkRemovedOptionModule
+    types
+  ;
+
+  cfg = config.services.prometheus.exporters.node;
+in {
+  imports = [
+    (mkRemovedOptionModule [ "services" "prometheus" "exporters" "node" "openFirewall" ] "No nix-darwin equivalent to this NixOS option.")
+    (mkRemovedOptionModule [ "services" "prometheus" "exporters" "node" "firewallFilter" ] "No nix-darwin equivalent to this NixOS option.")
+    (mkRemovedOptionModule [ "services" "prometheus" "exporters" "node" "firewallRules" ] "No nix-darwin equivalent to this NixOS option.")
+  ];
+
+  options = {
+    services.prometheus.exporters.node = {
+      enable = mkEnableOption "Prometheus Node exporter";
+
+      package = mkPackageOption pkgs "prometheus-node-exporter" { };
+
+      listenAddress = mkOption {
+        type = types.str;
+        default = "";
+        example = "0.0.0.0";
+        description = ''
+          Address where Node exporter exposes its HTTP interface. Leave empty to bind to all addresses.
+        '';
+      };
+
+      port = mkOption {
+        type = types.port;
+        default = 9100;
+        description = ''
+          Port where the Node exporter exposes its HTTP interface.
+        '';
+      };
+
+      extraFlags = mkOption {
+        type = types.listOf types.str;
+        default = [ ];
+        example = [ "--log.level=debug" ];
+        description = ''
+          Extra commandline options to pass to the Node exporter executable.
+        '';
+      };
+
+      enabledCollectors = mkOption {
+        type = types.listOf types.str;
+        default = [ ];
+        description = ''
+          Collectors to enable in addition to the ones that are [enabled by default](https://github.com/prometheus/node_exporter#enabled-by-default).
+        '';
+      };
+
+      disabledCollectors = mkOption {
+        type = types.listOf types.str;
+        default = [ ];
+        example = [ "boottime" ];
+        description = ''
+          Collectors to disable from the list of collectors that are [enabled by default](https://github.com/prometheus/node_exporter#enabled-by-default).
+        '';
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    users.users._prometheus-node-exporter = {
+      uid = config.ids.uids._prometheus-node-exporter;
+      gid = config.ids.gids._prometheus-node-exporter;
+      home = "/var/lib/prometheus-node-exporter";
+      createHome = true;
+      shell = "/usr/bin/false";
+      description = "System user for the Prometheus Node exporter";
+    };
+
+    users.groups._prometheus-node-exporter = {
+      gid = config.ids.gids._prometheus-node-exporter;
+      description = "System group for the Prometheus Node exporter";
+    };
+
+    users.knownGroups = [ "_prometheus-node-exporter" ];
+    users.knownUsers = [ "_prometheus-node-exporter" ];
+
+    launchd.daemons.prometheus-node-exporter = {
+      script = concatStringsSep " "
+        ([
+          (getExe cfg.package)
+          "--web.listen-address"
+          "${cfg.listenAddress}:${toString cfg.port}"
+        ]
+        ++ (map (collector: "--collector.${collector}") cfg.enabledCollectors)
+        ++ (map (collector: "--no-collector.${collector}") cfg.disabledCollectors)
+      ) + escapeShellArgs cfg.extraFlags;
+      serviceConfig = let
+        logPath = config.users.users._prometheus-node-exporter.home
+          + "/prometheus-node-exporter.log";
+      in {
+        KeepAlive = true;
+        RunAtLoad = true;
+        StandardErrorPath = logPath;
+        StandardOutPath = logPath;
+        GroupName = "_prometheus-node-exporter";
+        UserName = "_prometheus-node-exporter";
+      };
+    };
+  };
+}
diff --git a/modules/services/monitoring/telegraf.nix b/modules/services/monitoring/telegraf.nix
index e3d3250..f40e013 100644
--- a/modules/services/monitoring/telegraf.nix
+++ b/modules/services/monitoring/telegraf.nix
@@ -10,12 +10,12 @@ let
 in {
   options = {
     services.telegraf = {
-      enable = mkEnableOption (lib.mdDoc "telegraf agent");
+      enable = mkEnableOption "telegraf agent";
 
       package = mkOption {
         default = pkgs.telegraf;
         defaultText = lib.literalExpression "pkgs.telegraf";
-        description = lib.mdDoc "Which telegraf derivation to use";
+        description = "Which telegraf derivation to use";
         type = types.package;
       };
 
@@ -23,7 +23,7 @@ in {
         type = types.listOf types.path;
         default = [ ];
         example = [ "/run/keys/telegraf.env" ];
-        description = lib.mdDoc ''
+        description = ''
           File to load as environment file.
           This is useful to avoid putting secrets into the nix store.
         '';
@@ -31,7 +31,7 @@ in {
 
       extraConfig = mkOption {
         default = { };
-        description = lib.mdDoc "Extra configuration options for telegraf";
+        description = "Extra configuration options for telegraf";
         type = settingsFormat.type;
         example = {
           outputs.influxdb = {
@@ -47,7 +47,7 @@ in {
 
       configUrl = mkOption {
         default = null;
-        description = lib.mdDoc "Url to fetch config from";
+        description = "Url to fetch config from";
         type = types.nullOr types.str;
       };
     };