add basic options for programs.tmux

2 files changed, 86 insertions, 1 deletions

diff --git a/modules/environment.nix b/modules/environment.nix
index d2e0d14..58a5e25 100644
--- a/modules/environment.nix
+++ b/modules/environment.nix
@@ -39,6 +39,7 @@ in {
     };
 
     environment.variables = mkOption {
+      type = types.attrsOf (types.loeOf types.str);
       default = {};
       description = ''
         A set of environment variables used in the global environment.
@@ -47,7 +48,6 @@ in {
         strings.  The latter is concatenated, interspersed with colon
         characters.
       '';
-      type = types.attrsOf (types.loeOf types.str);
       apply = mapAttrs (n: v: if isList v then concatStringsSep ":" v else v);
     };
 
diff --git a/modules/tmux.nix b/modules/tmux.nix
new file mode 100644
index 0000000..249e015
--- /dev/null
+++ b/modules/tmux.nix
@@ -0,0 +1,85 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  inherit (pkgs) stdenv;
+
+  cfg = config.programs.tmux;
+
+  tmuxConfigs =
+    mapAttrsToList (n: v: "${v}") cfg.text;
+
+in {
+  options = {
+
+    programs.tmux.enableSensible = mkOption {
+      type = types.bool;
+      default = false;
+      example = true;
+      description = ''
+        Enable sensible configuration options.
+      '';
+    };
+
+    programs.tmux.enableVim = mkOption {
+      type = types.bool;
+      default = false;
+      example = true;
+      description = ''
+        Enable vim style keybindings for copy mode, and navigation of panes.
+      '';
+    };
+
+    programs.tmux.text = mkOption {
+      internal = true;
+      type = types.attrsOf types.str;
+      default = {};
+    };
+
+  };
+
+  config = {
+
+    system.build.setTmuxOptions = pkgs.writeText "set-tmux-options"
+      (concatStringsSep "\n" tmuxConfigs);
+
+    programs.tmux.text.sensible = mkIf cfg.enableSensible (''
+      set -g default-terminal "screen-256color"
+      setw -g aggressive-resize on
+
+      set -g base-index 1
+      set -g renumber-windows on
+      bind 0 set -g status
+
+      set -g status-keys emacs
+      set -s escape-time 0
+
+      bind c new-window -c '#{pane_current_path}'
+      bind % split-window -v -c '#{pane_current_path}'
+      bind '"' split-window -h -c '#{pane_current_path}'
+
+      # TODO: make these interactive
+      bind C new-session
+      bind S switch-client -l
+
+      # set -g status-utf8 on
+      # set -g utf8 on
+    '' + optionalString stdenv.isDarwin ''
+      set -g default-command "reattach-to-user-namespace -l $SHELL"
+    '');
+
+    programs.tmux.text.vim = mkIf cfg.enableVim ''
+      setw -g mode-keys vi
+
+      bind h select-pane -L
+      bind j select-pane -D
+      bind k select-pane -U
+      bind l select-pane -R
+      bind s split-window -v -c '#{pane_current_path}'
+      bind v split-window -h -c '#{pane_current_path}'
+    '';
+
+  };
+}