flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

{
  description = "Home Manager configuration";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    mvinkio.url = "github:mvinkio/nixpkgs/nixpkgs-unstable";
    nixpkgs-stable.url = "github:nixos/nixpkgs/nixos-22.05";
    sops-nix.url = "github:Mic92/sops-nix";
    home-manager = { url = "github:nix-community/home-manager"; inputs.nixpkgs.follows = "nixpkgs"; };
  };

  outputs = inputs@{
    self,
    nixpkgs,
    mvinkio,
    nixpkgs-stable,
    home-manager,
    sops-nix,
    ...
  }: let
    home = builtins.getEnv "HOME";
    username = builtins.getEnv "USER";
    email = builtins.getEnv "EMAIL";
    system = "x86_64-linux";
    mvinkioPkgs = mvinkio.legacyPackages.${system};

    overlay = nixpkgs.lib.composeManyExtensions [
      (import ./overlays/vimPlugins.nix {inherit pkgs;})
      (import ./overlays/suckless.nix {inherit pkgs home;})
    ];

    pkgs = import nixpkgs {
      overlays = [
        overlay
      ];
      inherit system;
    };

    lib = (nixpkgs.lib.extend (_: _: home-manager.lib)).extend (import ./lib);

  in with lib; {
    inherit lib;

    nixosConfigurations.lemptop = nixpkgs.lib.nixosSystem {
      inherit system;
      modules = [./configuration.nix ./lemptop.nix sops-nix.nixosModules.sops];
    };

    homeConfigurations.mike = home-manager.lib.homeManagerConfiguration {
      inherit pkgs;
      modules =
        (attrValues
          (attrsets.mergeAttrsList [
            (modulesIn ./home)
            (modulesIn ./email)
          ])) ++ [./home.nix];
      extraSpecialArgs = {
        inherit inputs username email;
      };
    };

    templates = {
      default = {
        path = ./templates/flake;
        description = "Flake with python and go stuff";
      };
      ansible = {
        path = ./templates/ansible;
        description = "Flake with ansible and shellhook to login to awx";
      };
      go = {
        path = ./templates/go;
        description = "Flake with go, gotools, and gofumpt";
      };
    };
  };
}