From f2d3d509d95943c00975c8a83dbb35907262e30b Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Cezary=20Dro=C5=BCak?= <cezdro@alatek.com.pl>
Date: Wed, 7 Sep 2022 10:30:43 +0200
Subject: feat: add jsonnet

---
 queries/jsonnet/highlights.scm | 76 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 queries/jsonnet/highlights.scm

(limited to 'queries')

diff --git a/queries/jsonnet/highlights.scm b/queries/jsonnet/highlights.scm
new file mode 100644
index 00000000..eb8d22be
--- /dev/null
+++ b/queries/jsonnet/highlights.scm
@@ -0,0 +1,76 @@
+[
+  (true)
+  (false)
+] @boolean
+
+(comment) @comment
+(id) @variable
+(import) @include
+(null) @constant.builtin
+(number) @number
+(string) @string
+
+(fieldname (id) @label)
+
+[
+  "["
+  "]"
+  "{"
+  "}"
+  "("
+  ")"
+] @punctuation.bracket
+
+[
+  "."
+  ","
+  ";"
+  ":"
+  "::"
+  ":::"
+] @punctuation.delimiter
+
+(expr
+  operator: (_) @operator)
+[
+  "+"
+  "="
+] @operator
+
+"in" @keyword.operator
+
+[
+ (local)
+ "assert"
+] @keyword
+
+[
+  "else"
+  "if"
+  "then"
+] @conditional
+
+[
+  (dollar)
+  (self)
+] @variable.builtin
+((id) @variable.builtin
+ (#eq? @variable.builtin "std"))
+
+; Function declaration
+(bind
+  function: (id) @function
+  params: (params
+            (param
+              identifier: (id) @parameter)))
+
+; Function call
+(expr
+  (expr (id) @function.call)
+  "("
+  (args
+    (named_argument
+      (id) @parameter))?
+  ")")
+
+(ERROR) @error
-- 
cgit v1.2.3